Vielleicht ist dir bei dem Programmbeispiel zur seriellen Kommunikation aufgefallen, dass der Taster beim Drücken nicht jedes Mal sofort von 0 auf 1 wechselt. Manchmal springt er ein paar Mal hin und her bis er konstant bei 1 bleibt. Das nennt man Prellen (englisch to bounce).

Das ist nicht schlimm wenn man etwas tun will, solange der Taster gedrückt ist. Will man aber eine Aktion jedes Mal wenn der Taster gedrückt wird ausführen, kann das Prellen zu Problemen führen: Obwohl der Taster nur einmal gedrückt wurde, nimmt der Arduino aufgrund des Prellens an, der Taster wäre zweimal schnell hintereinander betätigt worden.

Problematisch ist es zum Beispiel, wenn man mit dem Taster eine LED durch einmaliges Antippen des Tasters ein oder ausschalten will: Es kann passieren, dass die LED nur kurz aufblitzt und gleich wieder ausgeht. Um das zu verhindern, müssen wir den Taster entprellen (englisch debounce).

Baue zum Testen nochmal die Schaltung aus dem „Serielle Kommunikation“-Beispiel auf:

Zur Anzeige werden wir die interne LED des Arduino verwenden, die fest an Pin 13 verdrahtet und mit „L“ beschriftet ist.

Das Programm

// constants won't change. They're used here to
// set pin numbers:
const int buttonPin = 2;     // the number of the pushbutton pin
const int ledPin =  13;      // the number of the LED pin

// Variables will change:
int ledState = HIGH;         // the current state of the output pin
int buttonState;             // the current reading from the input pin
int lastButtonState = LOW;   // the previous reading from the input pin

// the following variables are long's because the time, measured in miliseconds,
// will quickly become a bigger number than can be stored in an int.
long lastDebounceTime = 0;  // the last time the output pin was toggled
long debounceDelay = 50;    // the debounce time; increase if the output flickers

void setup() {
  pinMode(buttonPin, INPUT);
  pinMode(ledPin, OUTPUT);
}

void loop() {
  // read the state of the switch into a local variable:
  int reading = digitalRead(buttonPin);

  // check to see if you just pressed the button
  // (i.e. the input went from LOW to HIGH),  and you've waited
  // long enough since the last press to ignore any noise:  

  // If the switch changed, due to noise or pressing:
  if (reading != lastButtonState) {
    // reset the debouncing timer
    lastDebounceTime = millis();
  }
 
  if ((millis() - lastDebounceTime) > debounceDelay) {
    // whatever the reading is at, it's been there for longer
    // than the debounce delay, so take it as the actual current state:
    buttonState = reading;
  }
 
  // set the LED using the state of the button:
  digitalWrite(ledPin, buttonState);

  // save the reading.  Next time through the loop,
  // it'll be the lastButtonState:
  lastButtonState = reading;
}

Zu Beginn des Programms werden einige Konstanten und Variablen definiert. Die Konstanten speichern, wo LED und Taster angeschlossen sind. In den Variablen merken wir uns, ob die LED gerade an oder aus sein soll, ob der Taster gedrückt ist, und ob er im Schritt zuvor gedrückt war (warum wir das brauchen kommt gleich).

Der Setup-Teil schaltet nun den Pin 2 als Eingang und den Pin 13 als Ausgang.

Im Loop wird zu Beginn des Schleifendurchlaufs die Taste mittels digitalRead abgefragt. Dieser Zustand wird in der Variable reading gespeichert. Wenn der Knopf im Schleifendurchlauf vorher noch nicht gedrückt war, ist reading ungleich lastButtonState. Dann merken wir uns den Zeitpunkt, zu dem das passiert ist. (millis gibt uns die Zeit in Millisekunden, seit der das Programm schon läuft). Hat sich der Zustand des Knopfes eine gewisse Zeit lang (debounceDelay) nicht verändert, setzen wir auch die Variable buttonState. An der LED wird nun der Zustand von buttonState angezeigt. Zu guter Letzt wird der jetztige Zustand des Knopfes in lastButtonState gespeichert, damit er bis zum nächsten Durchlauf der Schleife nicht verloren geht.

Das Programm tut also folgendes: Im Ruhezustand liegt am Pin 2 die „0“ an. Wird nun eine „1“ gelesen, merkt sich der Arduino das und wartet erstmal ab. Erst wenn nach Ablauf des debounceDelay immer noch eine „1“ an dem Pin anliegt, wird auch wirklich die buttonState-Variable umgeschaltet. Geht der Wert an Pin 2 zwischenzeitlich auf „0“, weil der Taster prellt, ist das nicht schlimm, denn buttonState wurde ja noch nicht umgeschaltet. Erst wenn die „1“ auch wirklich konstant eine Zeit lang (debounceDelay) anliegt, wird auch wirklich der buttonState gewechselt. (Wenn der Pin von „1“ auf „0“ wechselt, passiert das Gleiche genau umgekehrt.)

Frage: Was passiert, wenn das debounceDelay zu groß gewählt ist? Was, wenn es zu klein ist?

Transferaufgabe: Schreibe das Programm so um, dass die LED durch kurzes Antippen der Taste ein- und ausgeschaltet werden kann (also angeht, wenn man kurz draufdrückt, und erst wieder ausgeht, wenn man nochmal draufdrückt).

project/arduino-kickstarter-105.txt · Zuletzt geändert: 20.11.2013 22:27 von paalsteek
 
Falls nicht anders bezeichnet, ist der Inhalt dieses Wikis unter der folgenden Lizenz veröffentlicht: CC Attribution-Noncommercial-Share Alike 3.0 Unported
Recent changes RSS feed Driven by DokuWiki